توابع پایه اکسل - تابع IF 

تابع IF شرطی را بررسی می‌کند و زمانی که نتیجه بررسی TRUE باشد یک گزینه و زمانی که نتیجه FALSE باشد گزینه دیگری را بر می‌گرداند. بیش از یک شرط را می‌توان با توابع IF تودرتو بررسی کرد. تابع IF را می‌توان با توابع  AND، OR و NOT ترکیب کرد تا بررسی‌های منطقی پیشرفته‌تری انجام داد.

هدف تابع

یک شرط خاص را بررسی کنید.

خروجی تابع

مقادیری که برای TRUE یا FALSE ارائه می‌کنید

ترکیب تابع

= IF ( logical_test , [value_if_true] , [value_if_false] )

ورودی تابع (مولفه‌ها‌)

logical_test– یک مقدار یا عبارت منطقی که می‌تواند به عنوان TRUE یا FALSE ارزیابی شود.
value_if_true – [اختیاری] مقداری که نتیجه ارزیابی مولفه اول TRUE باشد.
value_if_false– [اختیاری] مقداری که نتیجه ارزیابی مولفه اول FALSE باشد.

نحوه استفاده از تابع

تابع IF یکی از پرکاربردترین توابع در اکسل است. این تابع در اصل شرطی را بررسی می‌کند، سپس زمانی که نتیجه TRUE باشد یک مقدار و زمانی که نتیجه FALSE باشد مقدار دیگری را بر می‌گرداند. در نگاه اول، عملکرد تابع ساده به نظر می‌رسد - اگر شرط درست است، این کار را انجام دهید ، در غیر این صورت، این کار را انجام دهید.

این مقاله اصول اولیه را با دقت معرفی می‌کند و سپس به توضیح بسیاری از فرمول‌های پیشرفته‌تر که از تابع IF استفاده می‌کنند، می‌پردازد. 

مثال‌ها

برای درک نحوه عملکرد تابع IF، اجازه دهید با یک مثال بسیار ابتدایی شروع کنیم. در برگه اکسل زیر، هدف استفاده از تابع IF برای مشخص کردن امتیازهای بیشتر از 80 است.

ساده‌ترین فرمولی که می‌توانیم برای آن بنویسیم به این صورت است:

= IF ( C3 > 80 , TRUE )

ترجمه: اگر مقدار سلول C3 بزرگتر از 80 است، TRUE را برگردانید.

 نتیجه را می‌توانید در برگه زیر مشاهده کنید.

توجه داشته باشید که از  نویسه نقل قول ("") در هیچ کجای فرمول استفاده نکردیم ، زیرا فرمول حاوی متن نیست. همچنین ، نیازی به ارائه مقدار برای مولفه value_if_false نداریم زیرا IF به طور پیش فرض FALSE را بر می‌گرداند.

این فرمول به خوبی کار می‌کند. اما خروجی نسبتا شلوغ است و خواندن آن سخت است. بیایید فرمول را تغییر دهیم تا وقتی امتیاز بیش از 80 باشد، یک نویسه ضربدر "x" بازگردانده شود:

= IF ( C3 > 80 , "x" )

توجه داشته باشید که نویسه ضربدر بین دو گیومه ظاهر می‌شود ، زیرا یک مقدار متنی است. مقادیر متنی که در فرمول‌ها استفاده می‌شوند همیشه باید بین دو گیومه قرار گیرند. در برگه زیر می‌توانید نتیجه را مشاهده کنید:

توجه داشته باشید که مقادیر TRUE با "x" جایگزین شده‌اند و نتایج  FALSE به همان شکل باقی می‌مانند زیرا مقداری برای value_if_false ارائه نکرده‌ایم.

در نهایت، بیایید فرمول را تغییر دهیم تا زمانی که امتیاز بیش از 80 نیست ، چیزی نمایش داده نشود. می‌توانیم این کار را با ارائه یک رشته خالی ("") برای مولفه value_if_false انجام دهیم:

= IF ( C3 > 80  ,"x" , "" )

پس از به‌روزرسانی فرمول‌های ستون E ، خواندن خروجی بسیار آسان‌تر است. اکنون نویسه x برای امتیازهای بیش از 80 درج می‌شود. برای امتیازهایی که بیش از 80 نیستند، سلول‌ها خالی باقی می‌ماند:

توجه: مقادیر متنی مانند "x" باید داخل دو گیومه محصور شوند. این عمل برای مقادیر عددی مانند 80 نیاز نیست.

مقایسه‌های منطقی

قبل از اینکه به ادامه مطلب بپردازیم، اجازه دهید در مورد نحوه عملکرد مقایسه‌‌های منطقی در تابع IF بیشتر صحبت کنیم. معمولاً مولفه logical_test در IF عبارتی است که TRUE یا FALSE را بر می‌‍گرداند.

جدول زیر چند نمونه رایج را نشان می‌دهد:

توجه داشته باشید که مقادیر متنی که در یک بررسی منطقی ظاهر می‌شوند باید داخل گیومه ("") محصور شوند. با این حال ، اعداد و عملگرهای منطقی مانند >،<،<>،=، و ... داخل گیومه نمی‌شوند.

توجه: تابع IF به حروف بزرگ و کوچک لاتین حساس نیست. 

مثال - قبول یا مردود

در برگه زیر، می‌خواهیم بر اساس نمره آزمون ، نتیجه «قبول» یا «مردود» اختصاص دهیم. نمره قبولی 70 یا بالاتر است. فرمول سلول E3 که در ردیف‌های زیرین نیز کپی شده، به شرح زیر است:

= IF ( C3 < 70 , "مردود" , "قبول" )

توجه داشته باشید که هر دو عبارت "قبول" و "مردود" داخل دو گیومه ("") قرار دارند زیرا مقادیر متنی هستند. همچنین توجه داشته باشید که جریان منطقی این فرمول قابل تغییر است. در برگه فوق ، ما برای نمرات مردودی بررسی انجام می‌دهیم. برای بررسی نمره قبولی، می‌توانیم فرمولی مانند این بنویسیم:

= IF ( C3 >= 70 , "قبول" , "مردود" )

ترجمه: اگر مقدار سلول C3 بزرگتر یا مساوی 70 باشد ، عبارت "قبول" بازگردانده شود. در غیر این صورت، "مردود" باز گردانده شود.

هر دو فرمول نتیجه یکسانی را بر می‌گردانند. اینکه کدام گزینه را انتخاب می‌کنید یک ترجیح شخصی است.

مثال – اگر این یا آن شرط برقرار باشد

یک چالش رایج با تابع IF بررسی مواردی است که به منطق " اگر این یا آن" نیاز دارد. مولفه اول تابع IF تنها یک شرط دریافت می‌کند ، بنابراین چگونه می‌توانید بیش از یک شرط را بررسی کنید؟

ترفند این است که تابع IF را با تابع OR ترکیب کنید. به عنوان مثال ، هدف در برگه زیر علامت گذاری ردیف‌هایی است که رنگ آن "قرمز" یا "سبز" است. می‌توانیم فرمولی بنویسیم که این کار را با ترکیب تابع IF با تابع OR به صورت زیر انجام دهد:

= IF ( OR ( B3 = "قرمز" , B3 = "سبز" ) , "x" ,"" )

ترجمه: اگر مقدار B3 "قرمز" یا "سبز" باشد ، "x" بازگردانده شود. در غیر این صورت، یک رشته خالی ("") بازگردانده شود.

توجه داشته باشید که تابع OR در داخل تابع IF به عنوان مولفه اول تعبیه شده است. تابع OR چندین عبارت منطقی می‌پذیرد. چنانچه نتیجه بررسی شرطی TRUE باشد ، تابع OR نتیجه TRUE را بر می‌گرداند. تنها در صورتی که نتیجه تمام شروط FALSE باشد، تابع OR  نتیجه FALSE را بر می‌گرداند. در برگه زیر می‌توانید نتیجه را مشاهده کنید:

مثال - اگر این و آن شرط برقرار باشد

مانند تابع OR  تابع AND را نیز می‌توان با تابع IF ترکیب کرد تا بررسی " اگر این و آن " ایجاد شود. در برگه زیر، هدف این است که افراد گروه B با حداقل نمره 80 را علامت‌گذاری کنیم. فرمول سلول F3، که در ردیف‌های زیرین نیز کپی شده، به صورت زیر است:

 = IF ( AND ( C3 = "B" , D3 > = 80 ) , "x" , "")

توجه داشته باشید که تابع AND در تابع IF به عنوان مولفه اول قرار دارد و شامل دو عبارت منطقی است: C3 = "B” و D3 >= 80 . نویسه B داخل نقل قول ("") ظاهر می‌شود زیرا یک رشته متن است. این کار برای 80 نیاز نیست زیرا یک مقدار عددی است.

مثال - اگر این و یا آن شرط برقرار باشد

برای پیاده سازی بررسی‌های پیشرفته‌تر ، می‌توانید توابع AND و OR را همزمان با IF ترکیب کنید.

در مثال زیر، هدف این است که افراد گروه A یا B با حداقل امتیاز 80 را علامت گذاری کنیم. فرمول موجود در سلول F3، که در سطر‌های زیرین نیز کپی شده ، به این صورت است:

= IF ( AND ( OR ( C3 = "A" , C3 = "B" ) , D3 >= 80 ) , "x" , "" )

مثال – IF های تودرتو

تابع IF را می‌توان به صورت"تودرتو" به کار برد. " IF تودرتو" به فرمولی اشاره دارد که در آن یک تابع IF داخل تابع IF دیگری قرار می‌گیرد تا شروط بیشتری را بررسی کند. هر عبارت IF باید با دقت در داخل دیگری قرار گیرد تا منطق تابع درست باشد. هدف در اینجا این است که چندین تابع IF را برای ایجاد منطق "در غیر این صورت اگر" را به هم متصل می‌کنیم. 

در مثال زیر، هدف این است که به هر رنگ یک عدد اختصاص دهیم. اگر رنگ قرمز باشد ، نتیجه باید 100 باشد. اگر رنگ آبی باشد ، نتیجه باید 125 و اگر رنگ سبز باشد ، نتیجه باید 150 باشد. در برگه زیر ، فرمول سلول D3 یک "IF تودرتو" است مانند این:

 = IF ( B3 = قرمز" , 100" , IF ( B3 = آبی" , 125" , IF ( B3 = سبز" , 150" )))

ترجمه: اگر رنگ قرمز است، 100 در غیر این صورت اگر رنگ آبی است ، 125 در غیر این صورت اگر رنگ سبز است ، 150بازگردانده شود.

توجه داشته باشید که این فرمول تنها سه رنگ قرمز ، آبی و سبز را مدیریت می‌کند. برای رنگ‌های دیگر، فرمول FALSE را بر می‌گرداند. همانطور که انتظار دارید، می‌توانید توابع IF بیشتری اضافه کنید تا مقادیر بیشتری را مدیریت کنید. 

 Excel گزینه‌های دیگری برای مدیریت چندین شرط دارد. به عنوان مثال، تابع IFS می‌تواند چندین شرط را بدون تودرتو کردن با فرمولی مانند زیر انجام دهد:

 = IFS ( B3 = قرمز" , 100" , B3 = آبی" , 125" , B3 = سبز" , 150" )

همچنین می توانید از تابع SWITCH با یک فرمول ساده تر مانند زیر استفاده کنید:

= SWITCH ( B3 , "قرمز" , 100 , "آبی" , 125 , "سبز" , 150 )

هر دو فرمول بالا نتیجه‌ای مشابه فرمول IF تودرتو اصلی را بر می‌گردانند.

توجه: برای سناریوهای پیچیده‌تر با مقادیر زیاد برای بررسی ، توابع دیگری مانند VLOOKUP یا XLOOKUP را در نظر بگیرید ، زیرا می‌توانند شرایط بیشتری را به شیوه‌ای ساده‌تر مدیریت کنند.

مثال – بازگرداندن فرمول دیگری با IF 

همانطور که مشاهده شد، تابع IF به راحتی می‌تواند مقدار دیگری را زمانی که نتیجه شرط TRUE یا FALSE باشد، برگرداند. علاوه بر این ، تابع IF همچنین می‌تواند یک فرمول را برگرداند.

به عنوان مثال ، در برگه زیر، هدف افزایش قیمت اقلام قرمز رنگ به مقدار 20 درصد است. قیمت اقلام با رنگ‌های دیگر باید بدون تغییر باقی بماند. فرمول سلول F3 به این صورت است:

= IF ( B3 = "قرمز" , D3 * 1.2 , D3 )

همانطور که فرمول در ردیف‌های زیرین کپی می‌شود، رنگ ستون B را بررسی می‌کند. اگر رنگ قرمز باشد، D3*1.2 را بر می‌گرداند و قیمت را 20% افزایش می‌دهد. اگر رنگ قرمز نباشد ، به سادگی D3 را بر می‌گرداند.

در برگه زیر می‌توانید نتیجه را مشاهده کنید:

به نتایج ستون F توجه کنید. بیشتر قیمت‌ها یکسان هستند، اما قیمت اقلام با رنگ قرمز اکنون 20 درصد بالاتر است. IF می‌تواند هر فرمول عادی اکسل را برای نتایج TRUE و FALSE برگرداند.

چه زمانی از IF استفاده نکنید

IF یک تابع پرکاربرد در اکسل است. با این حال ، فقط به این دلیل که IF رایج است به این معنی نیست که همیشه باید از آن استفاده کنید. اکسل توابع زیادی دارد که برای اعمال منطق «در غیر این صورت اگر» می‌توان استفاده کرد. به عنوان مثال، تابع همه‌کاره FILTER می‌تواند گزینه‌های منطبق را بر اساس معیارهای تطبیق استخراج کند، اما برای اعمال معیارها به IF نیاز ندارد. به همین ترتیب، COUNTIFS و SUMIFS می‌توانند مقادیر تطبیق را بر اساس معیارهای متعدد بدون IF شمارش/جمع کنند.

یادداشت 

•  تابع IF به حروف بزرگ و کوچک لاتین حساس نیست.
• در داخل IF، مقادیر متنی باید داخل دو گیومه ("") محصور شوند.
•  اعداد و مقادیر منطقی مانند TRUE و FALSE نباید داخل گیومه قرار گیرند.
• IF از نویسه‌های خاص پشتیبانی نمی‌کند ، اما می‌تواند با توابع دیگر ترکیب شود.
•  برای استخراج رکوردهایی که معیارهای خاصی دارند، به تابع FILTER مراجعه کنید.
•  برای شمارش مقادیری که معیارهای خاصی دارند، از توابع COUNTIF یا COUNTIFS استفاده کنید.
•  برای جمع مقادیری که معیارهای خاصی دارند، از SUMIF یا SUMIFS استفاده کنید.

لطفا دیدگاه خود را در کادر پایین با ما به اشتراک بگذارید.

آیا می‌خواهید:

• برنامه‌های قدرتمند و انعطاف پذیر با اکسل ایجاد کنید.
• فرصت های شغلی جدید کسب کنید.

کتاب‌های معرفی شده ، راهنمای گام به گام جامع و عملی برای افرادی است که (مانند شما) می‌خواهند به این اهداف برسند.